Emacs で現在の日時付きの名前でバックアップしてからセーブする

(defvar renban-copy-directory "~/.trash" "The directory for renban-copy.")
(defvar renban-copy-upper-limit-size (* 512 1024) "The upper limit of the file size for renban-copy.")

(defun renban-copy ()
  "現在のバッファに対応するファイルを filename.year-date-time という
書式で `renban-copy-directory' にコピーします。
`renban-copy-upper-limit-size' より大きなサイズのファイルはコピー
しません。"
  (unless renban-copy-directory
    (error "%s is nil." (symbol-name 'renban-copy-directory)))
  (let ((srcname buffer-file-name)
	(dir (expand-file-name renban-copy-directory))
	(dir-mode #o2700)
	dstname)
    (when (and srcname
	       (file-exists-p srcname)
	       (buffer-modified-p)
	       (<= (nth 7 (file-attributes srcname))
		   renban-copy-upper-limit-size))
      (unless (file-exists-p dir)
	(make-directory dir t))
      (unless (eq dir-mode (file-modes dir))
	(set-file-modes dir dir-mode))
      (setq dstname
	    (expand-file-name
	     (concat
	      (file-name-nondirectory srcname)
	      "."
	      (format-time-string "%y-%m%d-%H%M%S"))
	     dir))
      (message "Copying...")
      (copy-file srcname dstname t nil)
      (message "Copying...done."))))

(defadvice save-buffer
  (before
   save-buffer-before-advice
   activate)
  "save-buffer() の前に renban-copy() します。"
  (renban-copy))

(defadvice save-buffer
  (before
   save-buffer-before-advice
   activate)
  "save-buffer() の前に renban-copy() します。
ただし、引数が与えられたら renban-copy しません。"
  (let ((arg (ad-get-arg 0)))
    (if (or (null arg) (= arg 1))
	(renban-copy))))

(defun renban-copy-and-save (&optional arg)
  "renban-copy() してから save-buffer() します。
ただし、引数が与えられたら renban-copy() しません。"
  (interactive "P")
  (unless arg (renban-copy))
  (save-buffer))

(define-key ctl-x-map (kbd "C-s") 'renban-copy-and-save)